리스트박스에 현재 실행중인 process를 보여준후
선택한 process를 kill합니다. (kernel32.dll의 함수를 사용합니다)
그리고 uses절에 꼭 "TlHelp32" 를 추가해 주셔야 합니다.
저도 다른 사이트 돌면서 알게 된 방법입니다.
주의 하실 점은 Kernel32.dll은 죽이면 안되는거 아시죠... Windows먹통 됩니다...^^;

unit Unit1;

interface

uses
Windows, Messages, SysUtils, Classes, Graphics, Controls,
Forms, Dialogs, StdCtrls, TlHelp32;

type
TForm1 = class(TForm)
   ListBox1: TListBox;
   B_Search: TButton;
   B_Terminate: TButton;
   procedure B_SearchClick(Sender: TObject);
   procedure B_TerminateClick(Sender: TObject);
private
   { Private declarations }
public
   { Public declarations }
end;

var
Form1: TForm1;

implementation
{$R *.DFM}

// kernel32.dll을 사용하여 현재 떠있는 process를 읽어온다
procedure Process32List(Slist: TStrings);
var
    Process32: TProcessEntry32;
    SHandle:   THandle;  // the handle of the Windows object
    Next:      BOOL;
begin
    Process32.dwSize := SizeOf(TProcessEntry32);
    SHandle          := CreateToolHelp32Snapshot(TH32CS_SNAPPROCESS, 0);
   
    if Process32First(SHandle, Process32) then
        begin
        // 실행화일명과 process object 저장
        Slist.AddObject(Process32.szExeFile, TObject(Process32.th32ProcessID));
        repeat
            Next := Process32Next(SHandle, Process32);
            if Next then
                Slist.AddObject(Process32.szExeFile, TObject(Process32.th32ProcessID));
        until not Next;
        end;
    CloseHandle(SHandle);  // closes an open object handle
end;

procedure TForm1.B_SearchClick(Sender: TObject);
begin
    // 현재 실행중인 process를 검색
    ListBox1.Items.Clear;
    Process32List(ListBox1.Items);
end;

procedure TForm1.B_TerminateClick(Sender: TObject);
var
    hProcess: THandle;
    ProcId:   DWORD;
    TermSucc: BOOL;
begin
    // 현재 실행중인 process를 kill
    if ListBox1.ItemIndex < 0 then System.Exit;
    ProcId   := DWORD(ListBox1.Items.Objects[ListBox1.ItemIndex]);
    // 존재하는 process object의 handle을 return한다
    hProcess := OpenProcess(PROCESS_ALL_ACCESS, TRUE, ProcId);
    if hProcess = NULL then
        ShowMessage('OpenProcess error !');
    // 명시한 process를 강제 종료시킨다
    TermSucc := TerminateProcess(hProcess, 0);
    if TermSucc = FALSE then
        ShowMessage('TerminateProcess error !')
    else
        ShowMessage(Format('Process# %x terminated successfully !', [ProcId]));
end;

end.